You can not select more than 25 topics Topics must start with a chinese character,a letter or number, can include dashes ('-') and can be up to 35 characters long.

CMakeLists.txt 16 kB

9 years ago
5 years ago
9 years ago
5 years ago
9 years ago
9 years ago
9 years ago
9 years ago
123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462
  1. # Many projects still are stuck using CMake 2.8 is several places so it's good to provide backward support too. This is
  2. # specially true in old embedded systems (OpenWRT and friends) where CMake isn't necessarily upgraded.
  3. cmake_minimum_required(VERSION 2.8)
  4. if(POLICY CMP0048)
  5. cmake_policy(SET CMP0048 NEW)
  6. endif()
  7. # JSON-C library is C only project.
  8. project(json-c LANGUAGES C VERSION 0.14)
  9. # If we've got 3.0 then it's good, let's provide support. Otherwise, leave it be.
  10. if(POLICY CMP0038)
  11. # Policy CMP0038 introduced was in CMake 3.0
  12. cmake_policy(SET CMP0038 NEW)
  13. endif()
  14. if(POLICY CMP0054)
  15. cmake_policy(SET CMP0054 NEW)
  16. endif()
  17. # set default build type if not specified by user
  18. if(NOT CMAKE_BUILD_TYPE)
  19. set(CMAKE_BUILD_TYPE debug)
  20. endif()
  21. set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -O2")
  22. # Include file check macros honor CMAKE_REQUIRED_LIBRARIES
  23. # i.e. the check_include_file() calls will include -lm when checking.
  24. if(POLICY CMP0075)
  25. cmake_policy(SET CMP0075 NEW)
  26. endif()
  27. include(CTest)
  28. if (CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME AND BUILD_TESTING AND
  29. (NOT MSVC OR NOT (MSVC_VERSION LESS 1800)) # Tests need at least VS2013
  30. )
  31. add_subdirectory(tests)
  32. endif()
  33. # Set some packaging variables.
  34. set(CPACK_PACKAGE_NAME "${PROJECT_NAME}")
  35. set(CPACK_PACKAGE_VERSION_MAJOR "${PROJECT_VERSION_MAJOR}")
  36. set(CPACK_PACKAGE_VERSION_MINOR "${PROJECT_VERSION_MINOR}")
  37. set(CPACK_PACKAGE_VERSION_PATCH "${PROJECT_VERSION_PATCH}")
  38. set(JSON_C_BUGREPORT "json-c@googlegroups.com")
  39. set(CPACK_SOURCE_IGNORE_FILES
  40. ${PROJECT_SOURCE_DIR}/build
  41. ${PROJECT_SOURCE_DIR}/cmake-build-debug
  42. ${PROJECT_SOURCE_DIR}/pack
  43. ${PROJECT_SOURCE_DIR}/.idea
  44. ${PROJECT_SOURCE_DIR}/.DS_Store
  45. ${PROJECT_SOURCE_DIR}/.git
  46. ${PROJECT_SOURCE_DIR}/.vscode)
  47. include(CheckSymbolExists)
  48. include(CheckIncludeFile)
  49. include(CheckIncludeFiles)
  50. include(CheckCSourceCompiles)
  51. include(CheckTypeSize)
  52. include(CPack)
  53. include(GNUInstallDirs)
  54. include(CMakePackageConfigHelpers)
  55. option(BUILD_SHARED_LIBS "Default to building shared libraries" ON)
  56. option(BUILD_STATIC_LIBS "Default to building static libraries" ON)
  57. # Generate a release merge and test it to verify the correctness of republishing the package.
  58. ADD_CUSTOM_TARGET(distcheck
  59. COMMAND make package_source
  60. COMMAND tar -xvf "${PROJECT_NAME}-${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}.${PROJECT_VERSION_PATCH}-Source.tar.gz"
  61. COMMAND mkdir "${PROJECT_NAME}-${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}.${PROJECT_VERSION_PATCH}-Source/build"
  62. COMMAND cmake "${PROJECT_NAME}-${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}.${PROJECT_VERSION_PATCH}-Source/" -B"./${PROJECT_NAME}-${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}.${PROJECT_VERSION_PATCH}-Source/build/"
  63. COMMAND make -C "${PROJECT_NAME}-${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}.${PROJECT_VERSION_PATCH}-Source/build"
  64. COMMAND make test -C "${PROJECT_NAME}-${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}.${PROJECT_VERSION_PATCH}-Source/build"
  65. COMMAND rm -rf "${PROJECT_NAME}-${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}.${PROJECT_VERSION_PATCH}-Source"
  66. )
  67. # Enable or disable features. By default, all features are turned off.
  68. option(ENABLE_RDRAND "Enable RDRAND Hardware RNG Hash Seed" OFF)
  69. option(ENABLE_THREADING "Enable partial threading support." OFF)
  70. option(DISABLE_WERROR "Avoid treating compiler warnings as fatal errors" OFF)
  71. option(DISABLE_BSYMBOLIC "Avoid linking with -Bsymbolic-function" OFF)
  72. if (UNIX OR MINGW OR CYGWIN)
  73. list(APPEND CMAKE_REQUIRED_DEFINITIONS -D_GNU_SOURCE)
  74. endif()
  75. if (UNIX)
  76. list(APPEND CMAKE_REQUIRED_LIBRARIES m)
  77. endif()
  78. if (MSVC)
  79. list(APPEND CMAKE_REQUIRED_DEFINITIONS /D_CRT_SECURE_NO_DEPRECATE)
  80. list(APPEND CMAKE_REQUIRED_FLAGS /wd4996)
  81. endif()
  82. check_include_file("fcntl.h" HAVE_FCNTL_H)
  83. check_include_file("inttypes.h" HAVE_INTTYPES_H)
  84. check_include_file(stdarg.h HAVE_STDARG_H)
  85. check_include_file(strings.h HAVE_STRINGS_H)
  86. check_include_file(string.h HAVE_STRING_H)
  87. check_include_file(syslog.h HAVE_SYSLOG_H)
  88. check_include_files("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
  89. check_include_file(unistd.h HAVE_UNISTD_H)
  90. check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  91. check_include_file("dlfcn.h" HAVE_DLFCN_H)
  92. check_include_file("endian.h" HAVE_ENDIAN_H)
  93. check_include_file("limits.h" HAVE_LIMITS_H)
  94. check_include_file("locale.h" HAVE_LOCALE_H)
  95. check_include_file("memory.h" HAVE_MEMORY_H)
  96. check_include_file(stdint.h HAVE_STDINT_H)
  97. check_include_file(stdlib.h HAVE_STDLIB_H)
  98. check_include_file(sys/cdefs.h HAVE_SYS_CDEFS_H)
  99. check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  100. check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  101. check_include_file(xlocale.h HAVE_XLOCALE_H)
  102. if (HAVE_INTTYPES_H AND NOT MSVC)
  103. set(JSON_C_HAVE_INTTYPES_H 1)
  104. endif()
  105. check_symbol_exists(_isnan "float.h" HAVE_DECL__ISNAN)
  106. check_symbol_exists(_finite "float.h" HAVE_DECL__FINITE)
  107. if ((MSVC AND NOT (MSVC_VERSION LESS 1800)) OR MINGW OR CYGWIN OR UNIX)
  108. check_symbol_exists(INFINITY "math.h" HAVE_DECL_INFINITY)
  109. check_symbol_exists(isinf "math.h" HAVE_DECL_ISINF)
  110. check_symbol_exists(isnan "math.h" HAVE_DECL_ISNAN)
  111. check_symbol_exists(nan "math.h" HAVE_DECL_NAN)
  112. endif()
  113. check_symbol_exists(_doprnt "stdio.h" HAVE_DOPRNT)
  114. if (UNIX OR MINGW OR CYGWIN)
  115. check_symbol_exists(snprintf "stdio.h" HAVE_SNPRINTF)
  116. endif()
  117. check_symbol_exists(vasprintf "stdio.h" HAVE_VASPRINTF)
  118. check_symbol_exists(vsnprintf "stdio.h" HAVE_VSNPRINTF)
  119. check_symbol_exists(vprintf "stdio.h" HAVE_VPRINTF)
  120. if (HAVE_FCNTL_H)
  121. check_symbol_exists(open "fcntl.h" HAVE_OPEN)
  122. endif()
  123. if (HAVE_STDLIB_H)
  124. check_symbol_exists(realloc "stdlib.h" HAVE_REALLOC)
  125. endif()
  126. if (HAVE_LOCALE_H)
  127. check_symbol_exists(setlocale "locale.h" HAVE_SETLOCALE)
  128. check_symbol_exists(uselocale "locale.h" HAVE_USELOCALE)
  129. endif()
  130. if (HAVE_STRINGS_H)
  131. check_symbol_exists(strcasecmp "strings.h" HAVE_STRCASECMP)
  132. check_symbol_exists(strncasecmp "strings.h" HAVE_STRNCASECMP)
  133. endif()
  134. if (HAVE_STRING_H)
  135. check_symbol_exists(strdup "string.h" HAVE_STRDUP)
  136. check_symbol_exists(strerror "string.h" HAVE_STRERROR)
  137. endif()
  138. if (HAVE_SYSLOG_H)
  139. check_symbol_exists(vsyslog "syslog.h" HAVE_VSYSLOG)
  140. endif()
  141. check_symbol_exists(strtoll "stdlib.h" HAVE_STRTOLL)
  142. check_symbol_exists(strtoull "stdlib.h" HAVE_STRTOULL)
  143. set(json_c_strtoll "strtoll")
  144. if (NOT HAVE_STRTOLL)
  145. # Use _strtoi64 if strtoll is not available.
  146. check_symbol_exists(_strtoi64 "stdlib.h" __have_strtoi64)
  147. if (__have_strtoi64)
  148. #set(HAVE_STRTOLL 1)
  149. set(json_c_strtoll "_strtoi64")
  150. endif()
  151. endif()
  152. set(json_c_strtoull "strtoull")
  153. if (NOT HAVE_STRTOULL)
  154. # Use _strtoui64 if strtoull is not available.
  155. check_symbol_exists(_strtoui64 "stdlib.h" __have_strtoui64)
  156. if (__have_strtoui64)
  157. #set(HAVE_STRTOULL 1)
  158. set(json_c_strtoull "_strtoui64")
  159. endif()
  160. endif()
  161. check_type_size(int SIZEOF_INT)
  162. check_type_size(int64_t SIZEOF_INT64_T)
  163. check_type_size(long SIZEOF_LONG)
  164. check_type_size("long long" SIZEOF_LONG_LONG)
  165. check_type_size("size_t" SIZEOF_SIZE_T)
  166. check_c_source_compiles(
  167. [=[
  168. extern void json_object_get();
  169. __asm__(".section .gnu.json_object_get\\n\\t.ascii \\"Please link against libjson-c instead of libjson\\"\\n\\t.text");
  170. int main(int c, char *v) { return 0;}
  171. ]=]
  172. HAS_GNU_WARNING_LONG)
  173. check_c_source_compiles(
  174. "int main() { int i, x = 0; i = __sync_add_and_fetch(&x,1); return x; }"
  175. HAVE_ATOMIC_BUILTINS)
  176. check_c_source_compiles(
  177. "__thread int x = 0; int main() { return 0; }"
  178. HAVE___THREAD)
  179. if (HAVE___THREAD)
  180. set(SPEC___THREAD __thread)
  181. elseif (MSVC)
  182. set(SPEC___THREAD __declspec(thread))
  183. endif()
  184. # Hardware random number is not available on Windows? Says, config.h.win32. Best to preserve compatibility.
  185. if (WIN32)
  186. set(ENABLE_RDRAND 0)
  187. endif()
  188. # Once we've done basic symbol/header searches let's add them in.
  189. configure_file(${PROJECT_SOURCE_DIR}/cmake/config.h.in ${PROJECT_BINARY_DIR}/config.h)
  190. message(STATUS "Written ${PROJECT_BINARY_DIR}/config.h")
  191. configure_file(${PROJECT_SOURCE_DIR}/cmake/json_config.h.in ${PROJECT_BINARY_DIR}/json_config.h)
  192. message(STATUS "Written ${PROJECT_BINARY_DIR}/json_config.h")
  193. if ("${CMAKE_C_COMPILER_ID}" STREQUAL "GNU")
  194. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ffunction-sections -fdata-sections")
  195. if ("${DISABLE_WERROR}" STREQUAL "OFF")
  196. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror")
  197. endif()
  198. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
  199. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wcast-qual")
  200. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-error=deprecated-declarations")
  201. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wextra")
  202. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wwrite-strings")
  203. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-parameter")
  204. if (NOT WIN32)
  205. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wstrict-prototypes")
  206. endif()
  207. add_definitions(-D_GNU_SOURCE)
  208. elseif ("${CMAKE_C_COMPILER_ID}" STREQUAL "MSVC")
  209. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /DEBUG")
  210. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd4100")
  211. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd4996")
  212. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd4244")
  213. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd4706")
  214. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd4702")
  215. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd4127")
  216. set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd4701")
  217. endif()
  218. if (NOT ("${CMAKE_C_COMPILER_ID}" STREQUAL "MSVC"))
  219. check_c_source_compiles(
  220. [=[
  221. /* uClibc toolchains without threading barf when _REENTRANT is defined */
  222. #define _REENTRANT 1
  223. #include <sys/types.h>
  224. int main (void)
  225. {
  226. return 0;
  227. }
  228. ]=]
  229. REENTRANT_WORKS
  230. )
  231. if (REENTRANT_WORKS)
  232. add_compile_options("-D_REENTRANT")
  233. endif()
  234. # OSX Mach-O doesn't support linking with '-Bsymbolic-functions'.
  235. # Others may not support it, too.
  236. list(APPEND CMAKE_REQUIRED_LIBRARIES "-Wl,-Bsymbolic-functions")
  237. check_c_source_compiles(
  238. [=[
  239. int main (void)
  240. {
  241. return 0;
  242. }
  243. ]=]
  244. BSYMBOLIC_WORKS
  245. )
  246. list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES "-Wl,-Bsymbolic-functions")
  247. if (DISABLE_BSYMBOLIC STREQUAL "OFF" AND BSYMBOLIC_WORKS)
  248. set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-Bsymbolic-functions")
  249. # XXX need cmake>=3.13 for this:
  250. #add_link_options("-Wl,-Bsymbolic-functions")
  251. endif()
  252. endif()
  253. if ($ENV{VALGRIND})
  254. # Build so that valgrind doesn't complain about linkhash.c
  255. add_definitions(-DVALGRIND=1)
  256. endif()
  257. set(JSON_C_PUBLIC_HEADERS
  258. # Note: config.h is _not_ included here
  259. ${PROJECT_BINARY_DIR}/json_config.h
  260. ${PROJECT_SOURCE_DIR}/json.h
  261. ${PROJECT_SOURCE_DIR}/arraylist.h
  262. ${PROJECT_SOURCE_DIR}/debug.h
  263. ${PROJECT_SOURCE_DIR}/json_c_version.h
  264. ${PROJECT_SOURCE_DIR}/json_inttypes.h
  265. ${PROJECT_SOURCE_DIR}/json_object.h
  266. ${PROJECT_SOURCE_DIR}/json_object_iterator.h
  267. ${PROJECT_SOURCE_DIR}/json_pointer.h
  268. ${PROJECT_SOURCE_DIR}/json_tokener.h
  269. ${PROJECT_SOURCE_DIR}/json_types.h
  270. ${PROJECT_SOURCE_DIR}/json_util.h
  271. ${PROJECT_SOURCE_DIR}/json_visit.h
  272. ${PROJECT_SOURCE_DIR}/linkhash.h
  273. ${PROJECT_SOURCE_DIR}/printbuf.h
  274. )
  275. set(JSON_C_HEADERS
  276. ${JSON_C_PUBLIC_HEADERS}
  277. ${PROJECT_SOURCE_DIR}/json_object_private.h
  278. ${PROJECT_SOURCE_DIR}/random_seed.h
  279. ${PROJECT_SOURCE_DIR}/strerror_override.h
  280. ${PROJECT_SOURCE_DIR}/strerror_override_private.h
  281. ${PROJECT_SOURCE_DIR}/math_compat.h
  282. ${PROJECT_SOURCE_DIR}/snprintf_compat.h
  283. ${PROJECT_SOURCE_DIR}/strdup_compat.h
  284. ${PROJECT_SOURCE_DIR}/vasprintf_compat.h
  285. )
  286. set(JSON_C_SOURCES
  287. ${PROJECT_SOURCE_DIR}/arraylist.c
  288. ${PROJECT_SOURCE_DIR}/debug.c
  289. ${PROJECT_SOURCE_DIR}/json_c_version.c
  290. ${PROJECT_SOURCE_DIR}/json_object.c
  291. ${PROJECT_SOURCE_DIR}/json_object_iterator.c
  292. ${PROJECT_SOURCE_DIR}/json_pointer.c
  293. ${PROJECT_SOURCE_DIR}/json_tokener.c
  294. ${PROJECT_SOURCE_DIR}/json_util.c
  295. ${PROJECT_SOURCE_DIR}/json_visit.c
  296. ${PROJECT_SOURCE_DIR}/linkhash.c
  297. ${PROJECT_SOURCE_DIR}/printbuf.c
  298. ${PROJECT_SOURCE_DIR}/random_seed.c
  299. ${PROJECT_SOURCE_DIR}/strerror_override.c
  300. )
  301. include_directories(${PROJECT_SOURCE_DIR})
  302. include_directories(${PROJECT_BINARY_DIR})
  303. # generate doxygen documentation for json-c API
  304. find_package(Doxygen)
  305. option(BUILD_DOCUMENTATION "Create and install the HTML based API documentation(requires Doxygen)" ${DOXYGEN_FOUND})
  306. if (DOXYGEN_FOUND)
  307. add_custom_target(doc
  308. COMMAND ${DOXYGEN_EXECUTABLE} ${PROJECT_SOURCE_DIR}/Doxyfile
  309. WORKING_DIRECTORY ${PROJECT_BINARY_DIR})
  310. # request to configure the file
  311. configure_file(Doxyfile Doxyfile)
  312. else (DOXYGEN_FOUND)
  313. message("Warning: doxygen not found, the 'doc' target will not be included")
  314. endif(DOXYGEN_FOUND)
  315. # uninstall
  316. add_custom_target(uninstall
  317. COMMAND cat ${PROJECT_BINARY_DIR}/install_manifest.txt | xargs rm
  318. WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  319. )
  320. # XXX for a normal full distribution we'll need to figure out
  321. # XXX how to build both shared and static libraries.
  322. # Probably leverage that to build a local VALGRIND=1 library for testing too.
  323. add_library(${PROJECT_NAME}
  324. ${JSON_C_SOURCES}
  325. ${JSON_C_HEADERS}
  326. )
  327. set_target_properties(${PROJECT_NAME} PROPERTIES
  328. VERSION 5.0.0
  329. SOVERSION 5)
  330. list(APPEND CMAKE_TARGETS ${PROJECT_NAME})
  331. # If json-c is used as subroject it set to target correct interface -I flags and allow
  332. # to build external target without extra include_directories(...)
  333. target_include_directories(${PROJECT_NAME}
  334. PUBLIC
  335. $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}>
  336. $<BUILD_INTERFACE:${PROJECT_BINARY_DIR}>
  337. )
  338. # Allow to build static and shared libraries at the same time
  339. if (BUILD_STATIC_LIBS AND BUILD_SHARED_LIBS)
  340. set(STATIC_LIB ${PROJECT_NAME}-static)
  341. add_library(${STATIC_LIB} STATIC
  342. ${JSON_C_SOURCES}
  343. ${JSON_C_HEADERS}
  344. )
  345. # rename the static library
  346. if (NOT MSVC)
  347. set_target_properties(${STATIC_LIB} PROPERTIES
  348. OUTPUT_NAME ${PROJECT_NAME}
  349. )
  350. endif()
  351. list(APPEND CMAKE_TARGETS ${STATIC_LIB})
  352. endif ()
  353. # Always create new install dirs with 0755 permissions, regardless of umask
  354. set(CMAKE_INSTALL_DEFAULT_DIRECTORY_PERMISSIONS
  355. OWNER_READ
  356. OWNER_WRITE
  357. OWNER_EXECUTE
  358. GROUP_READ
  359. GROUP_EXECUTE
  360. WORLD_READ
  361. WORLD_EXECUTE
  362. )
  363. install(TARGETS ${CMAKE_TARGETS}
  364. EXPORT ${PROJECT_NAME}-targets
  365. RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  366. LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  367. ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  368. INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
  369. )
  370. install(EXPORT ${PROJECT_NAME}-targets
  371. FILE ${PROJECT_NAME}-targets.cmake
  372. NAMESPACE ${PROJECT_NAME}::
  373. DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
  374. )
  375. configure_package_config_file(
  376. "cmake/Config.cmake.in"
  377. ${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config.cmake
  378. INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}"
  379. )
  380. install(
  381. FILES ${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config.cmake
  382. DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
  383. )
  384. if (UNIX OR MINGW OR CYGWIN)
  385. SET(prefix ${CMAKE_INSTALL_PREFIX})
  386. # exec_prefix is prefix by default and CMake does not have the
  387. # concept.
  388. SET(exec_prefix ${CMAKE_INSTALL_PREFIX})
  389. SET(libdir ${CMAKE_INSTALL_FULL_LIBDIR})
  390. SET(includedir ${CMAKE_INSTALL_FULL_INCLUDEDIR})
  391. SET(VERSION ${PROJECT_VERSION})
  392. configure_file(json-c.pc.in json-c.pc @ONLY)
  393. set(INSTALL_PKGCONFIG_DIR "${CMAKE_INSTALL_LIBDIR}/pkgconfig" CACHE PATH "Installation directory for pkgconfig (.pc) files")
  394. install(FILES ${PROJECT_BINARY_DIR}/json-c.pc DESTINATION "${INSTALL_PKGCONFIG_DIR}")
  395. endif ()
  396. install(FILES ${JSON_C_PUBLIC_HEADERS} DESTINATION ${CMAKE_INSTALL_PREFIX}/include/json-c)