OSchip
/
OpenBLAS
Not watched
1
0
Fork 0
Code
Releases 66 Wiki evaluate Activity
Issues 0 Pull Requests 0 Datasets Model Cloudbrain HPC
You can not select more than 25 topics Topics must start with a chinese character,a letter or number, can include dashes ('-') and can be up to 35 characters long.
Tree: f66ca05b31
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'f66ca05b31'
${ noResults }
OpenBLAS/kernel/x86/scal_sse.S

638 lines
11 kB
Raw Blame History 

  1. /*********************************************************************/

  2. /* Copyright 2009, 2010 The University of Texas at Austin.           */

  3. /* All rights reserved.                                              */

  4. /*                                                                   */

  5. /* Redistribution and use in source and binary forms, with or        */

  6. /* without modification, are permitted provided that the following   */

  7. /* conditions are met:                                               */

  8. /*                                                                   */

  9. /*   1. Redistributions of source code must retain the above         */

  10. /*      copyright notice, this list of conditions and the following  */

  11. /*      disclaimer.                                                  */

  12. /*                                                                   */

  13. /*   2. Redistributions in binary form must reproduce the above      */

  14. /*      copyright notice, this list of conditions and the following  */

  15. /*      disclaimer in the documentation and/or other materials       */

  16. /*      provided with the distribution.                              */

  17. /*                                                                   */

  18. /*    THIS  SOFTWARE IS PROVIDED  BY THE  UNIVERSITY OF  TEXAS AT    */

  19. /*    AUSTIN  ``AS IS''  AND ANY  EXPRESS OR  IMPLIED WARRANTIES,    */

  20. /*    INCLUDING, BUT  NOT LIMITED  TO, THE IMPLIED  WARRANTIES OF    */

  21. /*    MERCHANTABILITY  AND FITNESS FOR  A PARTICULAR  PURPOSE ARE    */

  22. /*    DISCLAIMED.  IN  NO EVENT SHALL THE UNIVERSITY  OF TEXAS AT    */

  23. /*    AUSTIN OR CONTRIBUTORS BE  LIABLE FOR ANY DIRECT, INDIRECT,    */

  24. /*    INCIDENTAL,  SPECIAL, EXEMPLARY,  OR  CONSEQUENTIAL DAMAGES    */

  25. /*    (INCLUDING, BUT  NOT LIMITED TO,  PROCUREMENT OF SUBSTITUTE    */

  26. /*    GOODS  OR  SERVICES; LOSS  OF  USE,  DATA,  OR PROFITS;  OR    */

  27. /*    BUSINESS INTERRUPTION) HOWEVER CAUSED  AND ON ANY THEORY OF    */

  28. /*    LIABILITY, WHETHER  IN CONTRACT, STRICT  LIABILITY, OR TORT    */

  29. /*    (INCLUDING NEGLIGENCE OR OTHERWISE)  ARISING IN ANY WAY OUT    */

  30. /*    OF  THE  USE OF  THIS  SOFTWARE,  EVEN  IF ADVISED  OF  THE    */

  31. /*    POSSIBILITY OF SUCH DAMAGE.                                    */

  32. /*                                                                   */

  33. /* The views and conclusions contained in the software and           */

  34. /* documentation are those of the authors and should not be          */

  35. /* interpreted as representing official policies, either expressed   */

  36. /* or implied, of The University of Texas at Austin.                 */

  37. /*********************************************************************/

  38. 

  39. #define ASSEMBLER

  40. #include "common.h"

  41. 

  42. #define STACK	12

  43. #define ARGS     0

  44. 

  45. #define STACK_M	 	 4 + STACK + ARGS(%esp)

  46. #define STACK_ALPHA	16 + STACK + ARGS(%esp)

  47. #define STACK_X		20 + STACK + ARGS(%esp)

  48. #define STACK_INCX	24 + STACK + ARGS(%esp)

  49. 

  50. #define M	%ebx

  51. #define X	%ecx

  52. #define INCX	%edx

  53. #define I	%esi

  54. #define XX	%edi

  55. 

  56. #include "l1param.h"

  57. 

  58. 	PROLOGUE

  59. 

  60. 	pushl	%edi

  61. 	pushl	%esi

  62. 	pushl	%ebx

  63. 

  64. 	PROFCODE

  65. 

  66. 	movl	STACK_M,     M

  67. 	movl	STACK_X,     X

  68. 	movl	STACK_INCX,  INCX

  69. 

  70. 	lea	(, INCX, SIZE), INCX

  71. 

  72. 	movss	STACK_ALPHA, %xmm0

  73. 

  74. 	testl	M, M

  75. 	jle	.L999

  76. 

  77. 	xorps	%xmm1, %xmm1

  78. 	comiss	%xmm0, %xmm1

  79. 	shufps	$0, %xmm0, %xmm0

  80. 

  81. 	jne	.L100

  82. 

  83. /* Alpha == ZERO */

  84. 	cmpl	$SIZE, INCX

  85. 	jne	.L50

  86. 

  87. /* INCX == 1 */

  88. 	cmpl	$3, M

  89.  	jle	.L14

  90. 

  91. 	testl	$4, X		# aligned for double word?

  92. 	je	.L05

  93. 

  94. 	movss	%xmm1, 0 * SIZE(X)

  95. 	addl	$SIZE, X

  96. 	decl	M

  97. 	jle	.L999

  98. 	ALIGN_3

  99. 

  100. .L05:

  101. 	testl	$8, X		# aligned for quad word?

  102. 	je	.L06

  103. 

  104. 	movsd	%xmm1, 0 * SIZE(X)

  105. 	addl	$2 * SIZE, X

  106. 	subl	$2, M

  107. 	jle	.L999

  108. 	ALIGN_3

  109. 

  110. .L06:

  111. 	movl	M,  I

  112. 	sarl	$4, I

  113. 	jle	.L12

  114. 	ALIGN_4

  115. 

  116. .L11:

  117. #ifdef PREFETCHW

  118. 	PREFETCHW (PREFETCHSIZE +  0) - PREOFFSET(X)

  119. #endif

  120. 

  121. 	movaps	%xmm1,  0 * SIZE(X)

  122. 	movaps	%xmm1,  4 * SIZE(X)

  123. 	movaps	%xmm1,  8 * SIZE(X)

  124. 	movaps	%xmm1, 12 * SIZE(X)

  125. 	addl	$16 * SIZE, X

  126. 	decl	I

  127. 	jg	.L11

  128. 	ALIGN_4

  129. 

  130. .L12:

  131. 	testl	$15, M

  132. 	je	.L999

  133. 	testl	$8, M

  134. 	je	.L13

  135. 

  136. 	movaps	%xmm1,  0 * SIZE(X)

  137. 	movaps	%xmm1,  4 * SIZE(X)

  138. 	addl	$8 * SIZE, X

  139. 	ALIGN_3

  140. 

  141. .L13:

  142. 	testl  $4, M

  143. 	je    .L14

  144. 

  145. 	movaps	%xmm1,  0 * SIZE(X)

  146. 	addl	$4 * SIZE, X

  147. 	ALIGN_3

  148. 

  149. .L14:

  150. 	testl  $2, M

  151. 	je    .L15

  152. 

  153. 	movsd	%xmm1,  0 * SIZE(X)

  154. 	addl	$2 * SIZE, X

  155. 	ALIGN_3

  156. 

  157. .L15:

  158. 	testl  $1, M

  159. 	je    .L999

  160. 

  161. 	movss	%xmm1,  0 * SIZE(X)

  162. 	jmp	.L999

  163. 	ALIGN_4

  164. 

  165. /* incx != 1 */

  166. .L50:

  167. 	movl	M,  I		# rcx = n

  168. 	sarl	$3, I		# (n >> 3)

  169. 	jle	.L52

  170. 	ALIGN_4

  171. 

  172. .L51:

  173. #ifdef PREFETCHW

  174. 	PREFETCHW (PREFETCHSIZE +  0) - PREOFFSET(X)

  175. #endif

  176. 

  177. 	movss	%xmm1, (X)

  178. 	addl	INCX, X

  179. 	movss	%xmm1, (X)

  180. 	addl	INCX, X

  181. 	movss	%xmm1, (X)

  182. 	addl	INCX, X

  183. 	movss	%xmm1, (X)

  184. 	addl	INCX, X

  185. 	movss	%xmm1, (X)

  186. 	addl	INCX, X

  187. 	movss	%xmm1, (X)

  188. 	addl	INCX, X

  189. 	movss	%xmm1, (X)

  190. 	addl	INCX, X

  191. 	movss	%xmm1, (X)

  192. 	addl	INCX, X

  193. 

  194. 	decl	I

  195. 	jg	.L51

  196. 	ALIGN_4

  197. 

  198. .L52:

  199. 	testl	$7, M

  200. 	je	.L999

  201. 

  202. 	testl	$4, M

  203. 	je	.L53

  204. 

  205. 	movss	%xmm1, (X)

  206. 	addl	INCX, X

  207. 	movss	%xmm1, (X)

  208. 	addl	INCX, X

  209. 	movss	%xmm1, (X)

  210. 	addl	INCX, X

  211. 	movss	%xmm1, (X)

  212. 	addl	INCX, X

  213. 	ALIGN_3

  214. 

  215. .L53:

  216. 	testl	$2, M

  217. 	je	.L54

  218. 

  219. 	movss	%xmm1, (X)

  220. 	addl	INCX, X

  221. 	movss	%xmm1, (X)

  222. 	addl	INCX, X

  223. 	ALIGN_3

  224. 

  225. .L54:

  226. 	testl	$1, M

  227. 	je	.L999

  228. 

  229. 	movss	%xmm1, (X)

  230. 	jmp	.L999

  231. 	ALIGN_4

  232. 

  233. /* Alpha != ZERO */

  234. 

  235. .L100:

  236. 	cmpl	$SIZE, INCX

  237. 	jne	.L150

  238. 

  239. 	subl	$-32 * SIZE, X

  240. 

  241. 	cmpl	$3, M

  242. 	jle	.L116

  243. 

  244. 	testl	$SIZE, X

  245. 	je	.L105

  246. 

  247. 	movss	-32 * SIZE(X), %xmm1

  248. 	mulss	%xmm0, %xmm1

  249. 	movss	%xmm1, -32 * SIZE(X)

  250. 	addl	$SIZE, X

  251. 	decl	M

  252. 	jle	.L999

  253. 	ALIGN_3

  254. 

  255. .L105:

  256. 	testl	$2 * SIZE, X

  257. 	je	.L110

  258. 

  259. 	movsd	-32 * SIZE(X), %xmm1

  260. 	mulps	%xmm0, %xmm1

  261. 	movsd	%xmm1, -32 * SIZE(X)

  262. 	addl	$2 * SIZE, X

  263. 	subl	$2, M

  264. 	jle	.L999

  265. 	ALIGN_3

  266. 

  267. .L110:

  268. 	movl	M,  I

  269. 	sarl	$5, I

  270. 	jle	.L113

  271. 

  272. #if defined(BARCELONA) || defined(BULLDOZER)

  273. 

  274. 	movaps	%xmm0, %xmm1

  275. 	mulps	-32 * SIZE(X), %xmm1

  276. 	movaps	%xmm0, %xmm2

  277. 	mulps	-28 * SIZE(X), %xmm2

  278. 	movaps	%xmm0, %xmm3

  279. 	mulps	-24 * SIZE(X), %xmm3

  280. 	movaps	%xmm0, %xmm4

  281. 	mulps	-20 * SIZE(X), %xmm4

  282. 

  283. 	decl	I

  284. 	jle	.L112

  285. 	ALIGN_4

  286. 

  287. .L111:

  288. #ifdef PREFETCHW

  289. 	PREFETCHW (PREFETCHSIZE +  0) - PREOFFSET(X)

  290. #endif

  291. 

  292. 	movaps	%xmm1, -32 * SIZE(X)

  293. 	movaps	%xmm0, %xmm1

  294. 	mulps	-16 * SIZE(X), %xmm1

  295. 

  296. 	movaps	%xmm2, -28 * SIZE(X)

  297. 	movaps	%xmm0, %xmm2

  298. 	mulps	-12 * SIZE(X), %xmm2

  299. 

  300. 	movaps	%xmm3, -24 * SIZE(X)

  301. 	movaps	%xmm0, %xmm3

  302. 	mulps	 -8 * SIZE(X), %xmm3

  303. 

  304. 	movaps	%xmm4, -20 * SIZE(X)

  305. 	movaps	%xmm0, %xmm4

  306. 	mulps	 -4 * SIZE(X), %xmm4

  307. 

  308. #ifdef PREFETCHW

  309. 	PREFETCHW (PREFETCHSIZE + 64) - PREOFFSET(X)

  310. #endif

  311. 

  312. 	movaps	%xmm1, -16 * SIZE(X)

  313. 	movaps	%xmm0, %xmm1

  314. 	mulps	  0 * SIZE(X), %xmm1

  315. 

  316. 	movaps	%xmm2, -12 * SIZE(X)

  317. 	movaps	%xmm0, %xmm2

  318. 	mulps	  4 * SIZE(X), %xmm2

  319. 

  320. 	movaps	%xmm3,  -8 * SIZE(X)

  321. 	movaps	%xmm0, %xmm3

  322. 	mulps	  8 * SIZE(X), %xmm3

  323. 

  324. 	movaps	%xmm4,  -4 * SIZE(X)

  325. 	movaps	%xmm0, %xmm4

  326. 	mulps	 12 * SIZE(X), %xmm4

  327. 

  328. 	subl	$-32 * SIZE, X

  329. 	decl	I

  330. 	jg	.L111

  331. 	ALIGN_4

  332. 

  333. .L112:

  334. 	movaps	%xmm1, -32 * SIZE(X)

  335. 	movaps	%xmm0, %xmm1

  336. 	mulps	-16 * SIZE(X), %xmm1

  337. 

  338. 	movaps	%xmm2, -28 * SIZE(X)

  339. 	movaps	%xmm0, %xmm2

  340. 	mulps	-12 * SIZE(X), %xmm2

  341. 

  342. 	movaps	%xmm3, -24 * SIZE(X)

  343. 	movaps	%xmm0, %xmm3

  344. 	mulps	 -8 * SIZE(X), %xmm3

  345. 

  346. 	movaps	%xmm4, -20 * SIZE(X)

  347. 	movaps	%xmm0, %xmm4

  348. 	mulps	 -4 * SIZE(X), %xmm4

  349. 

  350. 	movaps	%xmm1, -16 * SIZE(X)

  351. 	movaps	%xmm2, -12 * SIZE(X)

  352. 	movaps	%xmm3,  -8 * SIZE(X)

  353. 	movaps	%xmm4,  -4 * SIZE(X)

  354. 

  355. #else

  356. 

  357. 	movaps	-32 * SIZE(X), %xmm1

  358. 	movaps	-28 * SIZE(X), %xmm2

  359. 	movaps	-24 * SIZE(X), %xmm3

  360. 	movaps	-20 * SIZE(X), %xmm4

  361. 

  362. 	decl	I

  363. 	jle	.L112

  364. 	ALIGN_4

  365. 

  366. .L111:

  367. #ifdef PREFETCHW

  368. 	PREFETCHW (PREFETCHSIZE +  0) - PREOFFSET(X)

  369. #endif

  370. 

  371. 	mulps	%xmm0, %xmm1

  372. 	movaps	%xmm1, -32 * SIZE(X)

  373. 	movaps	-16 * SIZE(X), %xmm1

  374. 

  375. 	mulps	%xmm0, %xmm2

  376. 	movaps	%xmm2, -28 * SIZE(X)

  377. 	movaps	-12 * SIZE(X), %xmm2

  378. 

  379. 	mulps	%xmm0, %xmm3

  380. 	movaps	%xmm3, -24 * SIZE(X)

  381. 	movaps	 -8 * SIZE(X), %xmm3

  382. 

  383. 	mulps	%xmm0, %xmm4

  384. 	movaps	%xmm4, -20 * SIZE(X)

  385. 	movaps	 -4 * SIZE(X), %xmm4

  386. 

  387. #ifdef PREFETCHW

  388. 	PREFETCHW (PREFETCHSIZE + 64) - PREOFFSET(X)

  389. #endif

  390. 

  391. 	mulps	%xmm0, %xmm1

  392. 	movaps	%xmm1, -16 * SIZE(X)

  393. 	movaps	  0 * SIZE(X), %xmm1

  394. 

  395. 	mulps	%xmm0, %xmm2

  396. 	movaps	%xmm2, -12 * SIZE(X)

  397. 	movaps	  4 * SIZE(X), %xmm2

  398. 

  399. 	mulps	%xmm0, %xmm3

  400. 	movaps	%xmm3,  -8 * SIZE(X)

  401. 	movaps	  8 * SIZE(X), %xmm3

  402. 

  403. 	mulps	%xmm0, %xmm4

  404. 	movaps	%xmm4,  -4 * SIZE(X)

  405. 	movaps	 12 * SIZE(X), %xmm4

  406. 

  407. 	subl	$-32 * SIZE, X

  408. 	decl	I

  409. 	jg	.L111

  410. 	ALIGN_4

  411. 

  412. .L112:

  413. 	mulps	%xmm0, %xmm1

  414. 	movaps	%xmm1, -32 * SIZE(X)

  415. 	movaps	-16 * SIZE(X), %xmm1

  416. 

  417. 	mulps	%xmm0, %xmm2

  418. 	movaps	%xmm2, -28 * SIZE(X)

  419. 	movaps	-12 * SIZE(X), %xmm2

  420. 

  421. 	mulps	%xmm0, %xmm3

  422. 	movaps	%xmm3, -24 * SIZE(X)

  423. 	movaps	 -8 * SIZE(X), %xmm3

  424. 

  425. 	mulps	%xmm0, %xmm4

  426. 	movaps	%xmm4, -20 * SIZE(X)

  427. 	movaps	 -4 * SIZE(X), %xmm4

  428. 

  429. 	mulps	%xmm0, %xmm1

  430. 	movaps	%xmm1, -16 * SIZE(X)

  431. 	mulps	%xmm0, %xmm2

  432. 	movaps	%xmm2, -12 * SIZE(X)

  433. 	mulps	%xmm0, %xmm3

  434. 	movaps	%xmm3,  -8 * SIZE(X)

  435. 	mulps	%xmm0, %xmm4

  436. 	movaps	%xmm4,  -4 * SIZE(X)

  437. 

  438. #endif

  439. 

  440. 	subl	$-32 * SIZE, X

  441. 	ALIGN_3

  442. 

  443. .L113:

  444. 	testl	$31, M

  445. 	je	.L999

  446. 

  447. 	testl	$16, M

  448. 	je	.L114

  449. 

  450. 	movaps	-32 * SIZE(X), %xmm1

  451. 	movaps	-28 * SIZE(X), %xmm3

  452. 	movaps	-24 * SIZE(X), %xmm5

  453. 	movaps	-20 * SIZE(X), %xmm7

  454. 

  455. 	mulps	%xmm0, %xmm1

  456. 	movaps	%xmm1, -32 * SIZE(X)

  457. 	mulps	%xmm0, %xmm3

  458. 	movaps	%xmm3, -28 * SIZE(X)

  459. 	mulps	%xmm0, %xmm5

  460. 	movaps	%xmm5, -24 * SIZE(X)

  461. 	mulps	%xmm0, %xmm7

  462. 	movaps	%xmm7, -20 * SIZE(X)

  463. 

  464. 	addl	$16 * SIZE, X

  465. 	ALIGN_3

  466. 

  467. .L114:

  468. 	testl	$8, M

  469. 	je	.L115

  470. 

  471. 	movaps	-32 * SIZE(X), %xmm1

  472. 	movaps	-28 * SIZE(X), %xmm3

  473. 

  474. 	mulps	%xmm0, %xmm1

  475. 	movaps	%xmm1, -32 * SIZE(X)

  476. 	mulps	%xmm0, %xmm3

  477. 	movaps	%xmm3, -28 * SIZE(X)

  478. 	addl	$8 * SIZE, X

  479. 	ALIGN_3

  480. 

  481. .L115:

  482. 	testl	$4, M

  483. 	je	.L116

  484. 

  485. 	movaps	-32 * SIZE(X), %xmm1

  486. 	mulps	%xmm0, %xmm1

  487. 	movaps	%xmm1, -32 * SIZE(X)

  488. 	addl	$4 * SIZE, X

  489. 	ALIGN_3

  490. 

  491. .L116:

  492. 	testl	$2, M

  493. 	je	.L117

  494. 

  495. 	movsd	-32 * SIZE(X), %xmm1

  496. 	mulps	%xmm0, %xmm1

  497. 	movsd	%xmm1,  -32 * SIZE(X)

  498. 	addl	$2 * SIZE, X

  499. 	ALIGN_3

  500. 

  501. .L117:

  502. 	testl	$1, M

  503. 	je	.L999

  504. 

  505. 	movss	-32 * SIZE(X), %xmm1

  506. 	mulss	%xmm0, %xmm1

  507. 	movss	%xmm1, -32 * SIZE(X)

  508. 	jmp	.L999

  509. 	ALIGN_3

  510. 

  511. /* incx != 1 */

  512. 

  513. .L150:

  514. 	movl	X, XX

  515. 	movl	M,  I		# rcx = n

  516. 	sarl	$3, I		# (n >> 3)

  517. 	jle	.L152

  518. 	ALIGN_4

  519. 

  520. .L151:

  521. 	movss	(X), %xmm1

  522. 	addl	INCX, X

  523. 	movss	(X), %xmm2

  524. 	addl	INCX, X

  525. 	movss	(X), %xmm3

  526. 	addl	INCX, X

  527. 	movss	(X), %xmm4

  528. 	addl	INCX, X

  529. 

  530. 	mulss	%xmm0, %xmm1

  531. 	mulss	%xmm0, %xmm2

  532. 	mulss	%xmm0, %xmm3

  533. 	mulss	%xmm0, %xmm4

  534. 

  535. 	movss	%xmm1, (XX)

  536. 	addl	INCX, XX

  537. 	movss	%xmm2, (XX)

  538. 	addl	INCX, XX

  539. 	movss	%xmm3, (XX)

  540. 	addl	INCX, XX

  541. 	movss	%xmm4, (XX)

  542. 	addl	INCX, XX

  543. 

  544. 	movss	(X), %xmm1

  545. 	addl	INCX, X

  546. 	movss	(X), %xmm2

  547. 	addl	INCX, X

  548. 	movss	(X), %xmm3

  549. 	addl	INCX, X

  550. 	movss	(X), %xmm4

  551. 	addl	INCX, X

  552. 

  553. 	mulss	%xmm0, %xmm1

  554. 	mulss	%xmm0, %xmm2

  555. 	mulss	%xmm0, %xmm3

  556. 	mulss	%xmm0, %xmm4

  557. 

  558. 	movss	%xmm1, (XX)

  559. 	addl	INCX, XX

  560. 	movss	%xmm2, (XX)

  561. 	addl	INCX, XX

  562. 	movss	%xmm3, (XX)

  563. 	addl	INCX, XX

  564. 	movss	%xmm4, (XX)

  565. 	addl	INCX, XX

  566. 

  567. 	decl	I

  568. 	jg	.L151

  569. 	ALIGN_4

  570. 

  571. .L152:

  572. 	testl	$7, M

  573. 	je	.L999

  574. 

  575. 	testl	$4, M

  576. 	je	.L153

  577. 

  578. 	movss	 (X), %xmm1

  579. 	addl	INCX, X

  580. 	movss	 (X), %xmm2

  581. 	addl	INCX, X

  582. 	movss	 (X), %xmm3

  583. 	addl	INCX, X

  584. 	movss	 (X), %xmm4

  585. 	addl	INCX, X

  586. 

  587. 	mulss	%xmm0, %xmm1

  588. 	mulss	%xmm0, %xmm2

  589. 	mulss	%xmm0, %xmm3

  590. 	mulss	%xmm0, %xmm4

  591. 

  592. 	movss	%xmm1,  (XX)

  593. 	addl	INCX, XX

  594. 	movss	%xmm2,  (XX)

  595. 	addl	INCX, XX

  596. 	movss	%xmm3,  (XX)

  597. 	addl	INCX, XX

  598. 	movss	%xmm4,  (XX)

  599. 	addl	INCX, XX

  600. 	ALIGN_3

  601. 

  602. .L153:

  603. 	testl	$2, M

  604. 	je	.L154

  605. 

  606. 	movss	 (X), %xmm1

  607. 	addl	INCX, X

  608. 	movss	 (X), %xmm2

  609. 	addl	INCX, X

  610. 

  611. 	mulss	%xmm0, %xmm1

  612. 	mulss	%xmm0, %xmm2

  613. 

  614. 	movss	%xmm1,  (XX)

  615. 	addl	INCX, XX

  616. 	movss	%xmm2,  (XX)

  617. 	addl	INCX, XX

  618. 	ALIGN_3

  619. 

  620. .L154:

  621. 	testl	$1, M

  622. 	je	.L999

  623. 

  624. 	movss	 (X), %xmm1

  625. 	mulss	%xmm0, %xmm1

  626. 	movss	%xmm1,  (X)

  627. 	ALIGN_4

  628. 

  629. .L999:

  630. 	xorl	%eax, %eax

  631. 

  632. 	popl	%ebx

  633. 	popl	%esi

  634. 	popl	%edi

  635. 	ret

  636. 

  637. 	EPILOGUE