OSchip
/
OpenBLAS
Not watched
1
0
Fork 0
Code
Releases 66 Wiki evaluate Activity
Issues 0 Pull Requests 0 Datasets Model Cloudbrain HPC
You can not select more than 25 topics Topics must start with a chinese character,a letter or number, can include dashes ('-') and can be up to 35 characters long.
Tree: 549a9f1dbb
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '549a9f1dbb'
${ noResults }
OpenBLAS/kernel/x86_64/scal_sse.S

617 lines
11 kB
Raw Blame History 

  1. /*********************************************************************/

  2. /* Copyright 2009, 2010 The University of Texas at Austin.           */

  3. /* All rights reserved.                                              */

  4. /*                                                                   */

  5. /* Redistribution and use in source and binary forms, with or        */

  6. /* without modification, are permitted provided that the following   */

  7. /* conditions are met:                                               */

  8. /*                                                                   */

  9. /*   1. Redistributions of source code must retain the above         */

  10. /*      copyright notice, this list of conditions and the following  */

  11. /*      disclaimer.                                                  */

  12. /*                                                                   */

  13. /*   2. Redistributions in binary form must reproduce the above      */

  14. /*      copyright notice, this list of conditions and the following  */

  15. /*      disclaimer in the documentation and/or other materials       */

  16. /*      provided with the distribution.                              */

  17. /*                                                                   */

  18. /*    THIS  SOFTWARE IS PROVIDED  BY THE  UNIVERSITY OF  TEXAS AT    */

  19. /*    AUSTIN  ``AS IS''  AND ANY  EXPRESS OR  IMPLIED WARRANTIES,    */

  20. /*    INCLUDING, BUT  NOT LIMITED  TO, THE IMPLIED  WARRANTIES OF    */

  21. /*    MERCHANTABILITY  AND FITNESS FOR  A PARTICULAR  PURPOSE ARE    */

  22. /*    DISCLAIMED.  IN  NO EVENT SHALL THE UNIVERSITY  OF TEXAS AT    */

  23. /*    AUSTIN OR CONTRIBUTORS BE  LIABLE FOR ANY DIRECT, INDIRECT,    */

  24. /*    INCIDENTAL,  SPECIAL, EXEMPLARY,  OR  CONSEQUENTIAL DAMAGES    */

  25. /*    (INCLUDING, BUT  NOT LIMITED TO,  PROCUREMENT OF SUBSTITUTE    */

  26. /*    GOODS  OR  SERVICES; LOSS  OF  USE,  DATA,  OR PROFITS;  OR    */

  27. /*    BUSINESS INTERRUPTION) HOWEVER CAUSED  AND ON ANY THEORY OF    */

  28. /*    LIABILITY, WHETHER  IN CONTRACT, STRICT  LIABILITY, OR TORT    */

  29. /*    (INCLUDING NEGLIGENCE OR OTHERWISE)  ARISING IN ANY WAY OUT    */

  30. /*    OF  THE  USE OF  THIS  SOFTWARE,  EVEN  IF ADVISED  OF  THE    */

  31. /*    POSSIBILITY OF SUCH DAMAGE.                                    */

  32. /*                                                                   */

  33. /* The views and conclusions contained in the software and           */

  34. /* documentation are those of the authors and should not be          */

  35. /* interpreted as representing official policies, either expressed   */

  36. /* or implied, of The University of Texas at Austin.                 */

  37. /*********************************************************************/

  38. 

  39. #define ASSEMBLER

  40. #include "common.h"

  41. 

  42. #ifndef WINDOWS_ABI

  43. #define M	ARG1

  44. #define X	ARG4

  45. #define INCX	ARG5

  46. #else

  47. #define M	ARG1

  48. #define X	ARG2

  49. #define INCX	ARG3

  50. #endif

  51. 

  52. #define XX	%r10

  53. #define I	%rax

  54. 

  55. #include "l1param.h"

  56. 

  57. 	PROLOGUE

  58. 	PROFCODE

  59. 

  60. #ifdef WINDOWS_ABI

  61. 	movq	40(%rsp), X

  62. 	movq	48(%rsp), INCX

  63. 	movq	64(%rsp), %r9

  64. 	movaps	%xmm3, %xmm0

  65. #else

  66. 	movq    24(%rsp), %r9

  67. #endif

  68. 

  69. 	SAVEREGISTERS

  70. 

  71. 	testq	M, M

  72. 	jle	.L999

  73. 

  74. 	lea	(, INCX, SIZE), INCX

  75. 

  76. 	pxor	%xmm1, %xmm1

  77. 	comiss	%xmm0, %xmm1

  78. 	shufps	$0, %xmm0, %xmm0

  79. 

  80. 	jne	.L100		# Alpha != ZERO

  81. 

  82. 	cmpq   $1, %r9

  83. 	je	.L100

  84. /* Alpha == ZERO */

  85. 	cmpq	$SIZE, INCX

  86. 	jne	.L50

  87. 

  88. /* INCX == 1 */

  89. 	cmpq	$3, M

  90.  	jle	.L14

  91. 

  92. 	testq	$4, X		# aligned for double word?

  93. 	je	.L05

  94. 

  95. 	movss	%xmm1, 0 * SIZE(X)

  96. 	addq	$SIZE, X

  97. 	decq	M

  98. 	jle	.L999

  99. 	ALIGN_3

  100. 

  101. .L05:

  102. 	testq	$8, X		# aligned for quad word?

  103. 	je	.L06

  104. 

  105. 	movsd	%xmm1, 0 * SIZE(X)

  106. 	addq	$2 * SIZE, X

  107. 	subq	$2, M

  108. 	jle	.L999

  109. 	ALIGN_3

  110. 

  111. .L06:

  112. 	movq	M,  I

  113. 	sarq	$4, I

  114. 	jle	.L12

  115. 	ALIGN_4

  116. 

  117. .L11:

  118. #ifdef PREFETCHW

  119. 	PREFETCHW (PREFETCHSIZE +  0) - PREOFFSET(X)

  120. #endif

  121. 

  122. 	movaps	%xmm1,  0 * SIZE(X)

  123. 	movaps	%xmm1,  4 * SIZE(X)

  124. 	movaps	%xmm1,  8 * SIZE(X)

  125. 	movaps	%xmm1, 12 * SIZE(X)

  126. 	addq	$16 * SIZE, X

  127. 	decq	I

  128. 	jg	.L11

  129. 	ALIGN_4

  130. 

  131. .L12:

  132. 	testq	$15, M

  133. 	je	.L999

  134. 	testq	$8, M

  135. 	je	.L13

  136. 

  137. 	movaps	%xmm1,  0 * SIZE(X)

  138. 	movaps	%xmm1,  4 * SIZE(X)

  139. 	addq	$8 * SIZE, X

  140. 	ALIGN_3

  141. 

  142. .L13:

  143. 	testq  $4, M

  144. 	je    .L14

  145. 

  146. 	movaps	%xmm1,  0 * SIZE(X)

  147. 	addq	$4 * SIZE, X

  148. 	ALIGN_3

  149. 

  150. .L14:

  151. 	testq  $2, M

  152. 	je    .L15

  153. 

  154. 	movsd	%xmm1,  0 * SIZE(X)

  155. 	addq	$2 * SIZE, X

  156. 	ALIGN_3

  157. 

  158. .L15:

  159. 	testq  $1, M

  160. 	je    .L999

  161. 

  162. 	movss	%xmm1,  0 * SIZE(X)

  163. 	jmp	.L999

  164. 	ALIGN_4

  165. 

  166. /* incx != 1 */

  167. .L50:

  168. 	movq	M,  I		# rcx = n

  169. 	sarq	$3, I		# (n >> 3)

  170. 	jle	.L52

  171. 	ALIGN_4

  172. 

  173. .L51:

  174. #ifdef PREFETCHW

  175. 	PREFETCHW (PREFETCHSIZE +  0) - PREOFFSET(X)

  176. #endif

  177. 

  178. 	movss	%xmm1, (X)

  179. 	addq	INCX, X

  180. 	movss	%xmm1, (X)

  181. 	addq	INCX, X

  182. 	movss	%xmm1, (X)

  183. 	addq	INCX, X

  184. 	movss	%xmm1, (X)

  185. 	addq	INCX, X

  186. 	movss	%xmm1, (X)

  187. 	addq	INCX, X

  188. 	movss	%xmm1, (X)

  189. 	addq	INCX, X

  190. 	movss	%xmm1, (X)

  191. 	addq	INCX, X

  192. 	movss	%xmm1, (X)

  193. 	addq	INCX, X

  194. 

  195. 	decq	I

  196. 	jg	.L51

  197. 	ALIGN_4

  198. 

  199. .L52:

  200. 	testq	$7, M

  201. 	je	.L999

  202. 

  203. 	testq	$4, M

  204. 	je	.L53

  205. 

  206. 	movss	%xmm1, (X)

  207. 	addq	INCX, X

  208. 	movss	%xmm1, (X)

  209. 	addq	INCX, X

  210. 	movss	%xmm1, (X)

  211. 	addq	INCX, X

  212. 	movss	%xmm1, (X)

  213. 	addq	INCX, X

  214. 	ALIGN_3

  215. 

  216. .L53:

  217. 	testq	$2, M

  218. 	je	.L54

  219. 

  220. 	movss	%xmm1, (X)

  221. 	addq	INCX, X

  222. 	movss	%xmm1, (X)

  223. 	addq	INCX, X

  224. 	ALIGN_3

  225. 

  226. .L54:

  227. 	testq	$1, M

  228. 	je	.L999

  229. 

  230. 	movss	%xmm1, (X)

  231. 	jmp	.L999

  232. 	ALIGN_4

  233. 

  234. /* Alpha != ZERO */

  235. 

  236. .L100:

  237. 	cmpq	$SIZE, INCX

  238. 	jne	.L150

  239. 

  240. 	subq	$-32 * SIZE, X

  241. 

  242. 	cmpq	$3, M

  243. 	jle	.L116

  244. 

  245. 	testq	$SIZE, X

  246. 	je	.L105

  247. 

  248. 	movss	-32 * SIZE(X), %xmm1

  249. 	mulss	%xmm0, %xmm1

  250. 	movss	%xmm1, -32 * SIZE(X)

  251. 	addq	$SIZE, X

  252. 	decq	M

  253. 	jle	.L999

  254. 	ALIGN_3

  255. 

  256. .L105:

  257. 	testq	$2 * SIZE, X

  258. 	je	.L110

  259. 

  260. 	movsd	-32 * SIZE(X), %xmm1

  261. 	mulps	%xmm0, %xmm1

  262. 	movsd	%xmm1, -32 * SIZE(X)

  263. 	addq	$2 * SIZE, X

  264. 	subq	$2, M

  265. 	jle	.L999

  266. 	ALIGN_3

  267. 

  268. .L110:

  269. 	movq	M,  I

  270. 	sarq	$5, I

  271. 	jle	.L113

  272. 

  273. #if defined(BARCELONA) || defined(SHANGHAI) || defined(BULLDOZER)

  274. 

  275. 	movaps	%xmm0, %xmm1

  276. 	mulps	-32 * SIZE(X), %xmm1

  277. 	movaps	%xmm0, %xmm2

  278. 	mulps	-28 * SIZE(X), %xmm2

  279. 	movaps	%xmm0, %xmm3

  280. 	mulps	-24 * SIZE(X), %xmm3

  281. 	movaps	%xmm0, %xmm4

  282. 	mulps	-20 * SIZE(X), %xmm4

  283. 	movaps	%xmm0, %xmm5

  284. 	mulps	-16 * SIZE(X), %xmm5

  285. 	movaps	%xmm0, %xmm6

  286. 	mulps	-12 * SIZE(X), %xmm6

  287. 	movaps	%xmm0, %xmm7

  288. 	mulps	 -8 * SIZE(X), %xmm7

  289. 	movaps	%xmm0, %xmm8

  290. 	mulps	 -4 * SIZE(X), %xmm8

  291. 

  292. 	decq	I

  293. 	jle	.L112

  294. 	ALIGN_4

  295. 

  296. .L111:

  297. #ifdef PREFETCHW

  298. 	PREFETCHW (PREFETCHSIZE +  0) - PREOFFSET(X)

  299. #endif

  300. 

  301. 	movaps	%xmm1, -32 * SIZE(X)

  302. 	movaps	%xmm2, -28 * SIZE(X)

  303. 	movaps	%xmm3, -24 * SIZE(X)

  304. 	movaps	%xmm4, -20 * SIZE(X)

  305. 

  306. 	movaps	%xmm0, %xmm1

  307. 	mulps	  0 * SIZE(X), %xmm1

  308. 	movaps	%xmm0, %xmm2

  309. 	mulps	  4 * SIZE(X), %xmm2

  310. 	movaps	%xmm0, %xmm3

  311. 	mulps	  8 * SIZE(X), %xmm3

  312. 	movaps	%xmm0, %xmm4

  313. 	mulps	 12 * SIZE(X), %xmm4

  314. 

  315. #ifdef PREFETCHW

  316. 	PREFETCHW (PREFETCHSIZE + 64) - PREOFFSET(X)

  317. #endif

  318. 

  319. 	movaps	%xmm5, -16 * SIZE(X)

  320. 	movaps	%xmm6, -12 * SIZE(X)

  321. 	movaps	%xmm7,  -8 * SIZE(X)

  322. 	movaps	%xmm8,  -4 * SIZE(X)

  323. 

  324. 	movaps	%xmm0, %xmm5

  325. 	mulps	 16 * SIZE(X), %xmm5

  326. 	movaps	%xmm0, %xmm6

  327. 	mulps	 20 * SIZE(X), %xmm6

  328. 	movaps	%xmm0, %xmm7

  329. 	mulps	 24 * SIZE(X), %xmm7

  330. 	movaps	%xmm0, %xmm8

  331. 	mulps	 28 * SIZE(X), %xmm8

  332. 

  333. 	subq	$-32 * SIZE, X

  334. 	decq	I

  335. 	jg	.L111

  336. 	ALIGN_4

  337. 

  338. .L112:

  339. 	movaps	%xmm1, -32 * SIZE(X)

  340. 	movaps	%xmm2, -28 * SIZE(X)

  341. 	movaps	%xmm3, -24 * SIZE(X)

  342. 	movaps	%xmm4, -20 * SIZE(X)

  343. 

  344. 	movaps	%xmm5, -16 * SIZE(X)

  345. 	movaps	%xmm6, -12 * SIZE(X)

  346. 	movaps	%xmm7,  -8 * SIZE(X)

  347. 	movaps	%xmm8,  -4 * SIZE(X)

  348. 

  349. #else

  350. 

  351. 	movaps	-32 * SIZE(X), %xmm1

  352. 	movaps	-28 * SIZE(X), %xmm2

  353. 	movaps	-24 * SIZE(X), %xmm3

  354. 	movaps	-20 * SIZE(X), %xmm4

  355. 	movaps	-16 * SIZE(X), %xmm5

  356. 	movaps	-12 * SIZE(X), %xmm6

  357. 	movaps	 -8 * SIZE(X), %xmm7

  358. 	movaps	 -4 * SIZE(X), %xmm8

  359. 	decq	I

  360. 	jle	.L112

  361. 	ALIGN_4

  362. 

  363. .L111:

  364. #ifdef PREFETCHW

  365. 	PREFETCHW (PREFETCHSIZE +  0) - PREOFFSET(X)

  366. #endif

  367. 

  368. 	mulps	%xmm0, %xmm1

  369. 	movaps	%xmm1, -32 * SIZE(X)

  370. 	movaps	 0 * SIZE(X), %xmm1

  371. 	mulps	%xmm0, %xmm2

  372. 	movaps	%xmm2, -28 * SIZE(X)

  373. 	movaps	 4 * SIZE(X), %xmm2

  374. 	mulps	%xmm0, %xmm3

  375. 	movaps	%xmm3, -24 * SIZE(X)

  376. 	movaps	 8 * SIZE(X), %xmm3

  377. 	mulps	%xmm0, %xmm4

  378. 	movaps	%xmm4, -20 * SIZE(X)

  379. 	movaps	12 * SIZE(X), %xmm4

  380. 

  381. #ifdef PREFETCHW

  382. 	PREFETCHW (PREFETCHSIZE + 64) - PREOFFSET(X)

  383. #endif

  384. 

  385. 	mulps	%xmm0, %xmm5

  386. 	movaps	%xmm5, -16 * SIZE(X)

  387. 	movaps	16 * SIZE(X), %xmm5

  388. 	mulps	%xmm0, %xmm6

  389. 	movaps	%xmm6, -12 * SIZE(X)

  390. 	movaps	20 * SIZE(X), %xmm6

  391. 	mulps	%xmm0, %xmm7

  392. 	movaps	%xmm7,  -8 * SIZE(X)

  393. 	movaps	24 * SIZE(X), %xmm7

  394. 	mulps	%xmm0, %xmm8

  395. 	movaps	%xmm8,  -4 * SIZE(X)

  396. 	movaps	28 * SIZE(X), %xmm8

  397. 

  398. 	subq	$-32 * SIZE, X

  399. 	decq	I

  400. 	jg	.L111

  401. 	ALIGN_4

  402. 

  403. .L112:

  404. 	mulps	%xmm0, %xmm1

  405. 	movaps	%xmm1, -32 * SIZE(X)

  406. 	mulps	%xmm0, %xmm2

  407. 	movaps	%xmm2, -28 * SIZE(X)

  408. 	mulps	%xmm0, %xmm3

  409. 	movaps	%xmm3, -24 * SIZE(X)

  410. 	mulps	%xmm0, %xmm4

  411. 	movaps	%xmm4, -20 * SIZE(X)

  412. 

  413. 	mulps	%xmm0, %xmm5

  414. 	movaps	%xmm5, -16 * SIZE(X)

  415. 	mulps	%xmm0, %xmm6

  416. 	movaps	%xmm6, -12 * SIZE(X)

  417. 	mulps	%xmm0, %xmm7

  418. 	movaps	%xmm7,  -8 * SIZE(X)

  419. 	mulps	%xmm0, %xmm8

  420. 	movaps	%xmm8,  -4 * SIZE(X)

  421. 

  422. #endif

  423. 

  424. 	subq	$-32 * SIZE, X

  425. 	ALIGN_3

  426. 

  427. .L113:

  428. 	testq	$31, M

  429. 	je	.L999

  430. 

  431. 	testq	$16, M

  432. 	je	.L114

  433. 

  434. 	movaps	-32 * SIZE(X), %xmm1

  435. 	movaps	-28 * SIZE(X), %xmm3

  436. 	movaps	-24 * SIZE(X), %xmm5

  437. 	movaps	-20 * SIZE(X), %xmm7

  438. 

  439. 	mulps	%xmm0, %xmm1

  440. 	movaps	%xmm1, -32 * SIZE(X)

  441. 	mulps	%xmm0, %xmm3

  442. 	movaps	%xmm3, -28 * SIZE(X)

  443. 	mulps	%xmm0, %xmm5

  444. 	movaps	%xmm5, -24 * SIZE(X)

  445. 	mulps	%xmm0, %xmm7

  446. 	movaps	%xmm7, -20 * SIZE(X)

  447. 

  448. 	addq	$16 * SIZE, X

  449. 	ALIGN_3

  450. 

  451. .L114:

  452. 	testq	$8, M

  453. 	je	.L115

  454. 

  455. 	movaps	-32 * SIZE(X), %xmm1

  456. 	movaps	-28 * SIZE(X), %xmm3

  457. 

  458. 	mulps	%xmm0, %xmm1

  459. 	movaps	%xmm1, -32 * SIZE(X)

  460. 	mulps	%xmm0, %xmm3

  461. 	movaps	%xmm3, -28 * SIZE(X)

  462. 	addq	$8 * SIZE, X

  463. 	ALIGN_3

  464. 

  465. .L115:

  466. 	testq	$4, M

  467. 	je	.L116

  468. 

  469. 	movaps	-32 * SIZE(X), %xmm1

  470. 	mulps	%xmm0, %xmm1

  471. 	movaps	%xmm1, -32 * SIZE(X)

  472. 	addq	$4 * SIZE, X

  473. 	ALIGN_3

  474. 

  475. .L116:

  476. 	testq	$2, M

  477. 	je	.L117

  478. 

  479. 	movsd	-32 * SIZE(X), %xmm1

  480. 	mulps	%xmm0, %xmm1

  481. 	movsd	%xmm1,  -32 * SIZE(X)

  482. 	addq	$2 * SIZE, X

  483. 	ALIGN_3

  484. 

  485. .L117:

  486. 	testq	$1, M

  487. 	je	.L999

  488. 

  489. 	movss	-32 * SIZE(X), %xmm1

  490. 	mulss	%xmm0, %xmm1

  491. 	movss	%xmm1, -32 * SIZE(X)

  492. 	jmp	.L999

  493. 	ALIGN_3

  494. 

  495. /* incx != 1 */

  496. 

  497. .L150:

  498. 	movq	X, XX

  499. 	movq	M,  I		# rcx = n

  500. 	sarq	$3, I		# (n >> 3)

  501. 	jle	.L152

  502. 	ALIGN_4

  503. 

  504. .L151:

  505. 	movss	(X), %xmm1

  506. 	addq	INCX, X

  507. 	movss	(X), %xmm2

  508. 	addq	INCX, X

  509. 	movss	(X), %xmm3

  510. 	addq	INCX, X

  511. 	movss	(X), %xmm4

  512. 	addq	INCX, X

  513. 	movss	(X), %xmm5

  514. 	addq	INCX, X

  515. 	movss	(X), %xmm6

  516. 	addq	INCX, X

  517. 	movss	(X), %xmm7

  518. 	addq	INCX, X

  519. 	movss	(X), %xmm8

  520. 	addq	INCX, X

  521. 

  522. 	mulss	%xmm0, %xmm1

  523. 	mulss	%xmm0, %xmm2

  524. 	mulss	%xmm0, %xmm3

  525. 	mulss	%xmm0, %xmm4

  526. 	mulss	%xmm0, %xmm5

  527. 	mulss	%xmm0, %xmm6

  528. 	mulss	%xmm0, %xmm7

  529. 	mulss	%xmm0, %xmm8

  530. 

  531. 	movss	%xmm1, (XX)

  532. 	addq	INCX, XX

  533. 	movss	%xmm2, (XX)

  534. 	addq	INCX, XX

  535. 	movss	%xmm3, (XX)

  536. 	addq	INCX, XX

  537. 	movss	%xmm4, (XX)

  538. 	addq	INCX, XX

  539. 	movss	%xmm5, (XX)

  540. 	addq	INCX, XX

  541. 	movss	%xmm6, (XX)

  542. 	addq	INCX, XX

  543. 	movss	%xmm7, (XX)

  544. 	addq	INCX, XX

  545. 	movss	%xmm8, (XX)

  546. 	addq	INCX, XX

  547. 	decq	I

  548. 	jg	.L151

  549. 	ALIGN_4

  550. 

  551. .L152:

  552. 	testq	$7, M

  553. 	je	.L999

  554. 

  555. 	testq	$4, M

  556. 	je	.L153

  557. 

  558. 	movss	 (X), %xmm1

  559. 	addq	INCX, X

  560. 	movss	 (X), %xmm2

  561. 	addq	INCX, X

  562. 	movss	 (X), %xmm3

  563. 	addq	INCX, X

  564. 	movss	 (X), %xmm4

  565. 	addq	INCX, X

  566. 

  567. 	mulss	%xmm0, %xmm1

  568. 	mulss	%xmm0, %xmm2

  569. 	mulss	%xmm0, %xmm3

  570. 	mulss	%xmm0, %xmm4

  571. 

  572. 	movss	%xmm1,  (XX)

  573. 	addq	INCX, XX

  574. 	movss	%xmm2,  (XX)

  575. 	addq	INCX, XX

  576. 	movss	%xmm3,  (XX)

  577. 	addq	INCX, XX

  578. 	movss	%xmm4,  (XX)

  579. 	addq	INCX, XX

  580. 	ALIGN_3

  581. 

  582. .L153:

  583. 	testq	$2, M

  584. 	je	.L154

  585. 

  586. 	movss	 (X), %xmm1

  587. 	addq	INCX, X

  588. 	movss	 (X), %xmm2

  589. 	addq	INCX, X

  590. 

  591. 	mulss	%xmm0, %xmm1

  592. 	mulss	%xmm0, %xmm2

  593. 

  594. 	movss	%xmm1,  (XX)

  595. 	addq	INCX, XX

  596. 	movss	%xmm2,  (XX)

  597. 	addq	INCX, XX

  598. 	ALIGN_3

  599. 

  600. .L154:

  601. 	testq	$1, M

  602. 	je	.L999

  603. 

  604. 	movss	 (X), %xmm1

  605. 	mulss	%xmm0, %xmm1

  606. 	movss	%xmm1,  (X)

  607. 	ALIGN_4

  608. 

  609. .L999:

  610. 	xorq	%rax, %rax

  611. 

  612. 	RESTOREREGISTERS

  613. 

  614. 	ret

  615. 

  616. 	EPILOGUE